Groovy는 평범한 자바의 while {...} 루프를 지원합니다:
| Code Block |
|---|
def x = 0
def y = 5
while ( y-- > 0 ) {
x++
}
assert x == 5
|
for 루프
Groovy의 for 루프는 매우 간결하며 배열, 콜랙션, 맵 등에 대해 모두 사용 가능합니다.
비고: 표준 for 루프는 beta-10 이전에는 구현되어 있지 않습니다
// for (int i = 0; i < 5; ++i) // beta-10 까지는 구현되지 않음
| Code Block |
|---|
// Range로 지정된 구간을 반복
def x = 0
for ( i in 0..9 ) {
x += i
}
assert x == 45
// List에 대해 반복
x = 0
for ( i in [0, 1, 2, 3, 4] ) {
x += i
}
assert x == 10
// 배열에 대해 반복
array = (0..4).toArray()
x = 0
for ( i in array ) {
x += i
}
assert x == 10
// Map에 대해 반복
def map = ['abc':1, 'def':2, 'xyz':3]
x = 0
for ( e in map ) {
x += e.value
}
assert x == 6
// Map의 값들에 대해 반복
x = 0
for ( v in map.values() ) {
x += v
}
assert x == 6
// String의 각 문자에 대해 반복
def text = "abc"
def list = []
for (c in text) {
list.add(c)
}
assert list == ["a", "b", "c"]
|
클로저
for 루프가 쓰일만한 대부분의 상황에서 루프 대신 each() 혹은 eachWithIndex()와 클로저를 사용할 수 있습니다:
| Code Block |
|---|
def stringList = [ "java", "perl", "python", "ruby", "c#", "cobol",
"groovy", "jython", "smalltalk", "prolog", "m", "yacc" ];
def stringMap = [ "Su" : "Sunday", "Mo" : "Monday", "Tu" : "Tuesday",
"We" : "Wednesday", "Th" : "Thursday", "Fr" : "Friday",
"Sa" : "Saturday" ];
stringList.each() { print " ${it}" }; println "";
// java perl python ruby c# cobol groovy jython smalltalk prolog m yacc
stringMap.each() { key, value -> println "${key} == ${value}" };
// Su == Sunday
// We == Wednesday
// Mo == Monday
// Sa == Saturday
// Th == Thursday
// Tu == Tuesday
// Fr == Friday
stringList.eachWithIndex() { obj, i -> println " ${i}: ${obj}" };
// 0: java
// 1: perl
// 2: python
// 3: ruby
// 4: c#
// 5: cobol
// 6: groovy
// 7: jython
// 8: smalltalk
// 9: prolog
// 10: m
// 11: yacc
stringMap.eachWithIndex() { obj, i -> println " ${i}: ${obj}" };
// 0: Su=Sunday
// 1: We=Wednesday
// 2: Mo=Monday
// 3: Sa=Saturday
// 4: Th=Thursday
// 5: Tu=Tuesday
// 6: Fr=Friday
|