Versions Compared

Key

  • This line was added.
  • This line was removed.
  • Formatting was changed.
Comment: Migrated to Confluence 5.3

Note: This page may not follow the explanations from the JLS.

Java has two basic informal rules for scoping:

Principle #1: "A variable is only visible in the block it is defined in and in nested blocks".
Principle #2: "A variable can't be visible more than one time".

Java does know classwide variables and local variables. Local variables are defined as method parameter or inside the method block. Classwide variables are defined as attributes of the class. Of course Java does violate this first principle I showed at top here a little since I can access class wide variables from outside the class, if the access modifier is for example public. A local variable of the same name as an attribute does not violate the second principle, as the attribute is hidden by the local variable and with this no longer visible without using a qualifier like "this".

Now, what about Groovy?

In Groovy we also have these two principles, but since we have different constructs, we may lay out these principles in a different way. Let us start with local variables.

  • In Groovy you are neither allowed to define two local variables of the same name, just like in Java.
  • You are allowed to hide an attribute by defining a local variable of the same name, just like in Java.

So what is different?

Scripts are. When you define a variable in a script it is always local. But methods are not part of that scope. So defining a method using different variables as if they were attributes and then defining these variables normally in the script leads to problems. Example:

Code Block
titleExample of disallowed definition in scripts
String attribute = "bar"
void aMethod(){
  assert attribute == "bar" // Not allowed !
}
aMethod()

Executing this code you get an exception talking about a missing property or field.

The only things the method has access to are:

  • the binding,
  • attributes defined by the base class, and
  • the dynamic properties defined by the MetaClass (explanations for these will follow).
    "attribute" here is no field, no property, no dynamic defined property and not part of the binding.

When is something in the Binding and when not?

That's easy. When it is not defined, it is in the binding.

Code Block
String localVar = "I am a local variable"
bindingVar = "I am a binding variable"

The trick is - and that is admittedly not easy for Java programers - to not to define the variable before using it, and it will go into the binding. Any defined variable is local. Please note: the binding exists only for scripts.

What is this "def" I heard of?

"def" is a replacement for a type name. In variable definitions it is used to indicate that you don't care about the type. In variable definitions it is mandatory to either provide a type name explicitly or to use "def" in replacement. This is needed to the make variable definitions detectable for the Groovy parser.

These definitions may occur for local variables in a script or for local variables and properties/fields in a class.

Tip
titleRule of thumb

You can think of "def" as an alias of "Object" and you will understand it in an instant.

"def" can also replace "void" as the return type in a method definiton.

Code Block
def dynamic  =  1
dynamic = "I am a String stored in a variable of dynamic type"
int typed = 2
typed = "I am a String stored in a variable of type int??"    // throws ClassCastException

The assignment of a string, to a variable of type int will fail. A variable typed with "def" allows this.

A Closure is a block

In the terms of the principles above a closure is a block. A variable defined in a block is visible in that block and all blocks that are defined in that block. For example in Java:

Code Block
titlea Java block
{
  int i=1;
  {
    System.out.println (i);
  }
}

Such a block may be defined freely as in the example above, or by loops, synchronized statements, try-catch, switch, ... all that has "{".

In Groovy we have an additonal structure with "{", the closure. To follow the principles above, it is not allowed to define two variables of the same name in a closure.

Code Block
titleNot allowed
def closure = { int i; int i }

And of course, the same for combinations with nested closures.

Code Block
titleinvalid double definition of variables
def outer = {
  int i
  def inner = { int i }
}

A block ends with its corresponding "}". So it is allowed to reuse that name later in a different block.

Code Block
titleAllowed
def closure1 = { parameter ->
  println parameter
}
def closure2 = { parameter ->
  println parameter
}

Both closures define a local varibale named "parameter", but since these closures are not nested, this is allowed. Note: unlike early versions of Groovy and unlike PHP, a variable is visible in the block, not outside. Just like in Java.

And "it"?

"it" is a special variable name, that is defined automatically inside a closure. It refers always to the first parameter of the closure, or null, if the closure doesn't have any parameters.

Code Block
titleimplicit it in closures
def c = { it }
assert c()  == null
assert c(1) == 1

When using nested cosures (closures in closures) the meaning of "it" depends on the closure you are in.

Code Block
def outer = {
  def inner = { it+1 }
  inner(it+1)
}
assert outer(1) == 3

You see, that "it" is used two times, the "it" in "inner" means the first parameter of the closure "inner", the following "it" means the first parameter of "outer". This helps a lot when copying code from one place to another containing closure that are using it.

The keyword "static"

"static" is a modifier for attributes (and methods, but this is not at issue here). It defines the "static scope". That means all variables not defined with "static" are not part of that static scope and as such not visible there. There is no special magic to this in Groovy. So for an explanation of "static" use any Java book.