View Source

Information

Java has in-built support for DOM processing of XML using classes representing the various parts of XML documents, e.g. Document, Element, NodeList, Attr etc. For more information about these classes, refer to the respective JavaDocs. Some of the key classes are:

DOM class	JavaDocs
Element	6 7
NodeList	6 7

Groovy syntax benefits can be applied when using these classes resulting in code which is similar to but more compact than the Java equivalent. In addition, Groovy supports the following built-in helper method for these classes.

DOM class	Method	Description/Equivalent longhand
NodeList	.iterator()	same as for loop, enables closures, e.g. findAll, every, etc.

In addition, the DOMCategory class provides numerous additional helper methods and syntax shortcuts:

DOM class	Method	Description/Equivalent longhand
Element	.'child' or .child or ['child']	similar to .getElementsByTagName('child') but only gets direct children
Element	.children() or .''* or ['']*	special case of above which finds all children regardless of tagname (plus text nodes)
Element	.'@attr' or ['@attr']	.getAttribute('attr')
Element	.attributes()	equivalent to .attributes returns a NamedNodeMap
Element	.text()	.firstChild.nodeValue (or textContent if you are using Xerces)
Element	.name()	.nodeName
Element	.parent() or .'..' or ['..']	.parentNode
Element	.depthFirst() or .''	depth-first traversal of nested children
Element	.breadthFirst()	breadth-first traversal of nested children
Node	.toString()	text node value as a String
NodeList	.size()	.length
NodeList	.list()	converted to a list of nodes
NodeList	[n]	.item(n)
NodeList	.text()	.collect{ it.text() }
NodeList	.child	flattened version of .child for each node in the NodeList
NamedNodeMap	.size()	.length
NamedNodeMap	.'child' or .child or ['child']	.getNamedItem(elementName).nodeValue

All these methods return standard Java classes (e.g. String and List) or standard DOM classes (e.g. Element, NodeList), so there are no new classes to learn, just some improved syntax.

Example

This example assumes the following class is already on your CLASSPATH:

Here is an example of using Groovy's DOMCategory:

import groovy.xml.DOMBuilder
import groovy.xml.dom.DOMCategory

messages = []

def processCar(car) {
    assert car.name() == 'car'
    def make = car.'@make'
    def country = car.country[0].text()
    def type = car.record[0].'@type'
    messages << make + ' of ' + country + ' has a ' + type + ' record'
}

def reader  = new StringReader(XmlExamples.CAR_RECORDS)
def doc     = DOMBuilder.parse(reader)
def records = doc.documentElement

use (DOMCategory) {
    assert 3 == records.'*'.size()
    def cars = records.'car'
    assert cars[0].parent() == records
    assert 3 == cars.size()
    assert 2 == cars.findAll{ it.'@year'.toInteger() > 1950 }.size()
    def carsByCentury = cars.list().groupBy{
        it.'@year'.toInteger() >= 2000 ? 'this century' : 'last century'
    }
    assert 1 == carsByCentury['this century'].size()
    assert 2 == carsByCentury['last century'].size()
    cars.each{ car -> processCar(car) }
}

assert messages == [
    'Holden of Australia has a speed record',
    'Peel of Isle of Man has a size record',
    'Bugatti of France has a price record'
]